WITH daysCte
(
	d 
)
AS
(
	SELECT CONVERT(DATETIME, '1 January 2011') AS d -- starting date
	UNION ALL
	SELECT DATEADD(D, 1, d)
	FROM daysCte
	WHERE DATEPART(yyyy, d) <= 2012 -- stop year
)
SELECT d, 
	   DATEPART(wk, d) AS week_number,
	   DATENAME(dw, d) AS day_name,
	   DATENAME(m, d) AS month_name,
	   DATENAME(q, d) AS [quarter]
FROM daysCte 
OPTION (MAXRECURSION 800); -- set > number of days you want data for

-- Create a temp table to hold log info
CREATE TABLE #tmp_log_info
(
      FileId INTEGER,
      FileSize BIGINT,
      StartOffSet BIGINT,
      [Status] INTEGER,
      FSeqNo INTEGER,
      Parity SMALLINT,
      CreateLSN NUMERIC(38,0)
);
 
-- Same as above but with database name
-- Can insert in one statement
CREATE TABLE #log_info
(
      FileId INTEGER,
      FileSize BIGINT,
      StartOffSet BIGINT,
      [Status] INTEGER,
      FSeqNo INTEGER,
      Parity SMALLINT,
      CreateLSN NUMERIC(38,0),
      [Database] VARCHAR(128)
);
 
EXEC sp_MsForEachDb 'INSERT INTO #tmp_log_info EXEC(''DBCC LOGINFO(?)'');
                              INSERT INTO #log_info
                               SELECT *, ''?''
                              FROM #tmp_log_info;
                              TRUNCATE TABLE #tmp_log_info;';
 
SELECT [Database],
            COUNT(*) AS Vlf_count,
            CAST(MAX(FileSize) AS FLOAT) / 1048576  AS biggest_vlf_MB,
            CAST(MIN(FileSize) AS FLOAT) / 1048576 AS smallest_vlf_MB
FROM #log_info
GROUP BY [Database]
ORDER BY COUNT(*) DESC;
 
 
-- Clean up
DROP TABLE #tmp_log_info;
DROP TABLE #log_info;

$server = "localhost";
# Load SMO 
[System.Reflection.Assembly]::LoadWithPartialName("Microsoft.SqlServer.Smo") | Out-Null; 
# create server objects 
$srv = New-Object Microsoft.SqlServer.Management.SMO.Server $server;
$db = $srv.Databases["tempdb"];
 
foreach($log in $db.LogFiles)
{
	Write-Host $log.Name;
	Write-Host "=================";
	# Output each property
	foreach($p in $log.Properties)
	{
		Write-Host $p.Name;
	}
}

CREATE TABLE dbo.Table1
(
	Id INTEGER NOT NULL PRIMARY KEY CLUSTERED,
	Value VARCHAR(20) NOT NULL
);
GO
 
CREATE TABLE dbo.Table2
(
	Id INTEGER NOT NULL PRIMARY KEY CLUSTERED,
	Value VARCHAR(20) NOT NULL
);
GO
 
-- Trigger on table 1
CREATE TRIGGER dbo.trg_Table1 ON dbo.Table1
AFTER INSERT
AS
BEGIN
	DECLARE @nest INTEGER;
	SET @nest = TRIGGER_NESTLEVEL();
 
	IF (@nest = 1)
	BEGIN
		INSERT INTO dbo.Table2
		(
			Id,
			Value
		)
		SELECT i.Id,
			   i.Value
		FROM inserted i;
	END
	ELSE
	BEGIN
		PRINT 'Trigger 1: Insert aborted trigger_nestlevel is ' + CAST(@nest AS VARCHAR(10));
	END
END
GO
 
-- Trigger on table 2
CREATE TRIGGER dbo.trg_Table2 ON dbo.Table2
AFTER INSERT
AS
BEGIN
	DECLARE @nest INTEGER;
	SET @nest = TRIGGER_NESTLEVEL();
 
	IF (@nest = 1)
	BEGIN
		INSERT INTO dbo.Table1
		(
			Id,
			Value
		)
		SELECT i.Id,
			   i.Value
		FROM inserted i;
	END
	ELSE
	BEGIN
		PRINT 'Trigger 2: Insert aborted trigger_nestlevel is ' + CAST(@nest AS VARCHAR(10));
	END	
END
GO

INSERT INTO dbo.Table1
(
	Id,
	Value
)
VALUES
(
	1,
	'Blah'
);

SELECT *
FROM dbo.Table1
UNION ALL
SELECT * 
FROM dbo.Table2;

INSERT INTO dbo.Table2
(
	Id,
	Value
)
VALUES
(
	2,
	'Blah'
);

SELECT *
FROM dbo.Table1
UNION ALL
SELECT * 
FROM dbo.Table2;

SELECT 'Net Transport' AS Property, CONNECTIONPROPERTY('net_transport') AS Value
UNION ALL
SELECT 'Protocol type', CONNECTIONPROPERTY('protocol_type')
UNION ALL
SELECT 'Auth scheme', CONNECTIONPROPERTY('auth_scheme')
UNION ALL
SELECT 'Local net address', CONNECTIONPROPERTY('local_net_address')
UNION ALL
SELECT 'Local TCP port', CONNECTIONPROPERTY('local_tcp_port')
UNION ALL
SELECT 'Client net address', CONNECTIONPROPERTY('client_net_address');

SELECT ENCRYPTBYPASSPHRASE('secret', 'My very secret text');

SELECT DECRYPTBYPASSPHRASE('secret', 0x010000006CF61B39AAF0030FDCED9942BEEEE946CB4EDB0AF2C0CDBCFB0B0882A7B32B4975974D20C8A3C82D);

SELECT CONVERT(VARCHAR(100), DECRYPTBYPASSPHRASE('secret', 0x010000006CF61B39AAF0030FDCED9942BEEEE946CB4EDB0AF2C0CDBCFB0B0882A7B32B4975974D20C8A3C82D));

DECLARE @passwords TABLE
(
	pwd VARCHAR(100)
)
 
INSERT INTO @passwords
(
	pwd
)
SELECT 'thomas'
UNION ALL
SELECT 'arsenal'
UNION ALL
SELECT 'monkey'
UNION ALL
SELECT 'charlie'
UNION ALL
SELECT 'qwerty'
UNION ALL
SELECT '123456'
UNION ALL
SELECT 'letmein'
UNION ALL
SELECT 'liverpool'
UNION ALL
SELECT 'password'
UNION ALL
SELECT '123'
UNION ALL
SELECT '';
 
-- List bad users
SELECT l.[name],
	   l.[sid],
	   p.pwd
FROM sys.sql_logins l
INNER JOIN @passwords p
	ON PWDCOMPARE(p.pwd, l.password_hash) = 1;

SELECT @@CONNECTIONS AS ConnectionAttempts,
	   @@CPU_BUSY AS CpuTime,
	   @@IDLE AS IdleTime,
	   @@IO_BUSY AS IoTime,
	   @@PACKET_ERRORS AS PacketErrors,
	   @@PACK_RECEIVED AS PacketsReceived,
	   @@PACK_SENT AS PacketsSent,
	   @@TIMETICKS AS MicrosecondsPerTick, -- Computer dependant
	   @@TOTAL_ERRORS AS TotalDiskWriteErrors,
	   @@TOTAL_READ AS TotalDiskReads,
	   @@TOTAL_WRITE AS TotalDiskWrites;

SELECT *
FROM fn_virtualfilestats (DB_ID(), NULL);

WITH MyCTE
(
	Company,
	Telephone
)
AS
(
	SELECT 'ACME LTD', '0123456789'
	UNION ALL
	SELECT 'Big Corp', '0987654321'
	UNION ALL
	SELECT 'Bobs Bits', '9999999999'
	UNION ALL
	SELECT 'Daves Hardware', '000000000000'
	UNION ALL
	SELECT 'Maestrosoft', '111111111111'
	UNION ALL
	SELECT 'Boracle Corp', '333333333333'
	UNION ALL
	SELECT 'White Dwarf Microsystems', '5555555555555'
	UNION ALL
	SELECT 'Big Telecom', '4444444444444'
	UNION ALL
	SELECT 'DOL', '666666666666'
	UNION ALL 
	SELECT 'London Media Ltd', '888888888888'
)
SELECT Company,
	   Telephone,
	   NTILE(3) OVER(ORDER BY Company) AS [Group]
FROM MyCTE;

WITH MyCTE
(
	Division,
	[Quarter],
	Value
)
AS
(
	SELECT 'Sales 1', 1, 0.12
	UNION ALL
	SELECT 'Sales 1', 1, 0.34
	UNION ALL
	SELECT 'Sales 1', 2, 0.45
	UNION ALL
	SELECT 'Sales 2', 3, 0.77
	UNION ALL
	SELECT 'Sales 2', 1, 0.55
	UNION ALL
	SELECT 'Sales 1', 3, 0.78
	UNION ALL
	SELECT 'Sales 2', 2, 0.45
	UNION ALL
	SELECT 'Sales 2', 4, 0.67
	UNION ALL
	SELECT 'Sales 1', 4, 0.77
)
SELECT Division,
	   [Quarter],
	   SUM(Value) AS SummedValue,
	   GROUPING(Division) AS IsDivisionGroup,
	   GROUPING([Quarter]) AS IsQuarterGroup,
	   GROUPING_ID(Division, [Quarter])
FROM MyCTE
GROUP BY Division,
		 [Quarter]
WITH ROLLUP
ORDER BY GROUPING_ID(Division, [Quarter]);

WITH MyCTE
(
	Division,
	[Quarter],
	Value
)
AS
(
	SELECT 'Sales 1', 1, 0.12
	UNION ALL
	SELECT 'Sales 1', 1, 0.34
	UNION ALL
	SELECT 'Sales 1', 2, 0.45
	UNION ALL
	SELECT 'Sales 2', 3, 0.77
	UNION ALL
	SELECT 'Sales 2', 1, 0.55
	UNION ALL
	SELECT 'Sales 1', 3, 0.78
	UNION ALL
	SELECT 'Sales 2', 2, 0.45
	UNION ALL
	SELECT 'Sales 2', 4, 0.67
	UNION ALL
	SELECT 'Sales 1', 4, 0.77
)
SELECT Division,
	   [Quarter],
	   SUM(Value) AS SummedValue,
	   GROUPING(Division) AS IsDivisionGroup,
	   GROUPING([Quarter]) AS IsQuarterGroup
FROM MyCTE
GROUP BY Division,
		 [Quarter]
WITH ROLLUP;